Codigo Plus

Descargar Archivo
Titulo	Reproductor de mp3 para el mirc KentMp3
Descripcion	Bueno este reproductor lo termine a finales del 2004 es un poco antiguo, después de eso me aleje del irc, pero creando este reproductor aprendí un poco del scripting, espero que les guste
Descargas	203
Codigo Fuente
<pre><font face='Verdana,Tahoma'>;el bueno
on *:load:{ 
  set %mostrar no
  set %kcontinuo no
  set %k3radio 1
  set %k3check
  set %k3bsi si
  set %k3carpeta c:\ 
  set %k3darch c:\ 
  set %kb3dir c:\
  set %k3color.inicio KentMp3[Autor:
  set %k3color.segundo  ^^ Tema:
  set %k3color.tercero  ][ Duracion:
  set %k3color.cuarto  ^^ Tamaño:
  set %k3color.ultimo  Mb]
  write -c kmp3lista.txt
  echo -a reproductor de Mp3 By Kentsuo instalado xD
}
;***********************dialogos********************************
dialog kentmp3 { 
  title "KentMp3 By [kentsuo]" 

  size -1 -1 358 400 
  ;icon 100,1 1 358 400,00_kof01.jpg
  option pixels notheme 
  box "Mostrar Cancion en los canales ???",1,10 10 170 70
  radio "Todos",2,30 25 80 20,right,group
  radio "No mostrar",3,30 40 80 20,right
  radio "En algunos",21,30 55 80 20,right
  button "Canales",22, 115 55 50 20
  button "Colores",19, 115 25 50 20
  check "Musica Continua",5,220 10 120 20 
  text "Volumen",4, 242 55 56 20
  button "--",6, 220 50 20 20
  button "+",7, 285 50 20 20
  button "Play", 8, 100 96 158 24, flat 
  button "Pause", 9, 16 96 74 24, flat 
  button "resume", 10, 16 96 74 24, flat 
  button "Parar", 11, 268 96 74 24, flat 
  box "Agregar",13,10 343 90 50
  button "&Car", 14, 60 362 30 24, flat 
  button "&Arc", 15, 20 362 30 24, flat 
  box "Eliminar",25,110 343 90 50
  button "A&rc", 26, 120 362 30 24, flat 
  button "&list", 16, 160 362 30 24, flat 
  button "&Buscar Mp3" 17, 240 360 70 20
  list 18, 12 130 338 200, size vsbar 
} 

dialog k3busca {
  title "KentMp3 Buscador de mp3z" 
  size 300 100 358 400 
  text "buscar" 1, 20 20 40 15 
  edit "" 2, 60 18 270 20,autohs
  list 3, 12 70 338 200, size vsbar
  box "Que hacer al elegir tema ??",4,10 280 170 100 
  radio "Solo agregar a la lista",5,30 300 130 20,right,group
  radio "Agregar a la lista y tocar",6,30 320 135 20,right
  radio "Solo tocar",7,30 340 130 20,right
  check "Cerrar al Elegir Tema ", 20, 200 290 150 20
  button "&Directorio del Buscador", 9, 200 330 140 24, flat  
}

dialog k3canales {
  title "KentMp3 Canales"
  size -1 -1 200 175
  text "Ingrese Canal:",23,20 10 65 30
  edit "",24,70 15 100 20,autohs
  text "Lista de Canales",25,20 45 80 20
  list 26, 10 66 110 100, size vsbar
  button "&Agregar",27,135 75 50 20
  button "&Eliminar",28,135 100 50 20
  button "&Cerrar",29,135 140 50 20, cancel

}

dialog k3colores {
  title "KentMp  colores        «Edita tus colores y Mensajes aqui»"
  size -1 -1 670 80 
  edit "",30,20 20 80 20, autohs
  text "@Autor",31,110 20 40 20  
  edit "",32,155 20 80 20, autohs
  text "@Tema",33,245 20 40 20  
  edit "",34,290 20 80 20, autohs
  text "@Tiempo",35,375 20 50 20 
  edit "",36,430 20 80 20, autohs
  text "@Peso",37,515 20 50 20 
  edit "",38,570 20 80 20, autohs
  button "&Aceptar",39,400 50 100 20, ok
  button "&Cancelar",40,550 50 100 20, cancel
  ;scroll "tema", 50, 20 60 80 10,boton,izquierda,horizontal,rango 10 10
}


;*********************alias**********************************
alias k3abrir.re {
  if (!$dialog(kentmp3)) { kentmp3 }
  else { echo -a 4,1ERROR el reproductor kentmp3 ya se encuentra activo }
}


;***alias kentmp3
alias kentmp3 dialog -md kentmp3 kentmp3 
alias k3lista var %aux = $findfile(%k3carpeta,*.mp3,0,did -a kentmp3 18 $nopath($1-)) 
alias k3gravar var %aux = $findfile(%k3carpeta,*.mp3,0,write kmp3lista.txt $1-)
alias k3abrir {
  set %ki 1
  set %kruta $read(kmp3lista.txt,%ki)
  while (%kruta != $null) {
    did -a kentmp3 18 $nopath(%kruta)     
    ;echo -s $nopath(%kruta)
    inc %ki 1
    set %kruta $read(kmp3lista.txt,%ki)
  } 
  unset %ki | unset %kruta
}

alias k3mostrar.algunos {
  set %ki 1
  set %k3canal $read(k3canales.txt, %ki)
  while (%k3canal != $null) {
    if (%k3sii == si) { 
      msg %k3canal %k3color.inicio $iif($mp3($insong.fname).artist != $null,$mp3($insong.fname).artist,$nopath($left(%kbdir,-1))) %k3color.segundo $iif($mp3($insong.fname).title != $null,$mp3($insong.fname).title,$remove(%k3tema,.mp3)) %k3color.tercero $duration($calc($lof($findfile(%k3bdir,%k3btema,1)) / 16000)) %k3color.cuarto $round($calc($lof($findfile(%k3bdir,%k3btema,1))/1048576),2) %k3color.ultimo
    } 
    else {
      msg %k3canal %k3color.inicio $iif($mp3($insong.fname).artist != $null,$mp3($insong.fname).artist,%k3autor) %k3color.segundo $iif($mp3($insong.fname).title != $null,$mp3($insong.fname).title,$remove(%k3tema,.mp3)) %k3color.tercero $duration($calc($lof(%k3dir $+ $did(kentmp3,18).seltext) / 16000)) %k3color.cuarto $round($calc($lof(%k3dir $+ $did(kentmp3,18).seltext)/1048576),2) %k3color.ultimo
    }
    inc %ki 1 
    set %k3canal $read(k3canales.txt, %ki) 
  }
  set %k3sii no
}

alias tocar { 
  if ($did(kentmp3,18).seltext) { 
    set %k3dir $nofile($read(kmp3lista.txt, w,* $+ $did(kentmp3,18).seltext))
    set %k3autor $nopath($left(%k3dir,-1))
    set %k3tema $did(kentmp3,18).seltext
    .splay %k3dir $+ %k3tema
    if (%mostrar == si) {
      .timer 1 1 amsg %k3color.inicio $iif($mp3($insong.fname).artist != $null,$mp3($insong.fname).artist,%k3autor) %k3color.segundo $iif($mp3($insong.fname).title != $null,$mp3($insong.fname).title,$remove(%k3tema,.mp3)) %k3color.tercero $duration($calc($lof(%k3dir $+ $did(kentmp3,18).seltext) / 16000)) %k3color.cuarto $round($calc($lof(%k3dir $+ $did(kentmp3,18).seltext)/1048576),2) %k3color.ultimo
      unset %k3dir | unset %tema
    } 
    if (%mostrar == sino) { .timer 1 1 k3mostrar.algunos }

  } 
  else { echo -a 4,1ERROR en KentMp3 ... debes eligir un tema }
}

alias kentmp3.volumen {
  if (%k3vol < 0) { set %k3vol 0 }
  if (%k3vol > 65535) { set %k3vol 65535 }
  .vol -p %k3vol
}

;**********alias k3busca

alias k3busca dialog -md k3busca k3busca
alias k3blista var %aux = $findfile(%k3bdir,*.mp3,0,did -a k3busca 3 $nopath($1-))
alias k3blista2 var %aux = $findfile(%k3bdir,* $+ $replace(%k3btema,$chr(32),*) $+ *.mp3,0,did -a k3busca 3 $nopath($1-))
alias k3agrega {
  did -a kentmp3 18 $did(k3busca,3).seltext
  write kmp3lista.txt $findfile(%k3bdir,$did(k3busca,3).seltext,1)
}

alias mostrar {
  set %k3tema %k3btema
  if (%mostrar == si) {
    .timer 1 1 amsg %k3color.inicio $iif($mp3($insong.fname).artist != $null,$mp3($insong.fname).artist,$nopath($left(%k3bdir,-1))) %k3color.segundo $iif($mp3($insong.fname).title != $null,$mp3($insong.fname).title,$remove(%k3btema,.mp3)) %k3color.tercero $duration($calc($lof($findfile(%k3bdir,%k3btema,1)) / 16000)) %k3color.cuarto $round($calc($lof($findfile(%k3bdir,%k3btema,1))/1048576),2) %k3color.ultimo
  } 
  if (%mostrar == sino) { set %k3sii si | .timer 1 1 k3mostrar.algunos }
}

alias tocar2 {
  set %kbdir $findfile(%k3bdir,$did(k3busca,3).seltext,1)
  .splay -p %kbdir
  set %kbdir $nofile(%kbdir)
  mostrar 
}

;******** k3canales

alias k3canales dialog -md k3canales k3canales 
alias k3canal.add {
  if (%k3canal != $null) {   

    if ($read(k3canales.txt, w, * $+ %k3canal) != $null) {
    echo -a 4,1 ERROR El Canal  $+ $did(k3canales,26).seltext $+  ya existe }
    else {
      .write k3canales.txt $chr(35) $+ %k3canal
      .did -a k3canales 26 $chr(35) $+ %k3canal
    }
    set %k3canal $null
    did -r k3canales 24
  }
}

alias k3canal.llenar {
  set %ki 1
  set %kaux $read(k3canales.txt, %ki)
  while (%kaux != $null) {
    .did -a k3canales 26 %kaux
    inc %ki 1
    set %kaux $read(k3canales.txt, %ki)
  }
  unset %kaux | unset %ki
}

alias k3canal.del {
  if ($did(k3canales,26).seltext) {
    .write -dl $+ $did(k3canales,26).sel k3canales.txt 
    .did -d k3canales 26 $did(k3canales,26).sel
  } 
  else { 
  echo -a 4,1ERROR deves escojer un canal }
}

alias k3arch.del {
  if ($did(kentmp3,18).seltext) {
    .write -dl $+ $did(kentmp3,18).sel kmp3lista.txt
    .did -d kentmp3 18 $did(kentmp3,18).sel
  } 
  else { 
  echo -a 4,1ERROR deves escojer un tema }
}

alias verificar {
  set %k3canal $read(k3canales.txt,1)
  if (%k3canal == $null) { k3canales | .echo -a 4,1 ERROR  no as ingresado ningun canal | .did -c kentmp3 3 | set %mostrar no | did -u kentmp3 21 }
}

;****k3colores

alias k3colores dialog -md k3colores k3colores

;************************eventos*******************
on 1:dialog:kentmp3:init:0:{ 
  k3abrir
  set %k3vol $vol(mp3)
  if (%mostrar == no) { did -c kentmp3 3 }
  if (%mostrar == si) { did -c kentmp3 2 }
  if (%mostrar == sino) { did -c kentmp3 21 }
  if (%kcontinuo == si) { did -c kentmp3 5 }
  did -h kentmp3 10 | did -v kentmp3 9 | did -f kentmp3 18 | .splay stop
} 
on 1:dialog:kentmp3:sclick:2:{ set %mostrar si }
on 1:dialog:kentmp3:sclick:3:{ set %mostrar no }
on 1:dialog:kentmp3:sclick:21:{ set %mostrar sino | verificar }
on 1:dialog:kentmp3:sclick:6:{ set %k3vol $calc(%k3vol - 4369) | kentmp3.volumen }
on 1:dialog:kentmp3:sclick:7:{ set %k3vol $calc(%k3vol + 4369) | kentmp3.volumen }
on 1:dialog:kentmp3:sclick:19:{ 
  if (!$dialog(k3colores)) { k3colores }
  else { echo -a 4,1ERROR la ventana de colores ya se encuentra activa }
}
on 1:dialog:kentmp3:sclick:5:{ 
  if (%Kcontinuo == no) { set %kcontinuo si }
  else { set %kcontinuo no }
}
on 1:dialog:kentmp3:sclick:8:{ tocar | did -h kentmp3 10 | did -v kentmp3 9 | set %k3tema $did(kentmp3,18).seltext | set %k3conre $did(kentmp3,18).seltext } 
on 1:dialog:kentmp3:sclick:9:{ 
  if $mp3($insong.fname) {    
  splay pause | did -h kentmp3 9 | did -v kentmp3 10 }
  else {
  echo -a 4,1ERROR no hay tema reproduciendose }
}
on 1:dialog:kentmp3:sclick:10:{ splay resume | did -h kentmp3 10 | did -v kentmp3 9 }
on 1:dialog:kentmp3:sclick:11:{ splay stop | did -h kentmp3 10 | did -v kentmp3 9 } 
on 1:dialog:kentmp3:sclick:14:{ set %k3carpeta $$sdir(%k3carpeta ,Selecciona una Carpeta) | k3lista | k3gravar } 
on 1:dialog:kentmp3:sclick:22:{ 
  if (!$dialog(k3canales)) { k3canales }
  else { echo -a 4,1ERROR la ventana canales ya se encuentra activa }
}
on 1:dialog:kentmp3:sclick:15:{ set %k3mp3 $dir="Elige un MP3" [ %k3darch $+ *.mp3 ] 
  if (%k3mp3 != $null) { 
    did -a kentmp3 18 $nopath(%k3mp3) 
    write kmp3lista.txt %k3mp3 
    set %k3darch $nofile(%k3mp3)
  }
}
on 1:dialog:kentmp3:sclick:16:{ .did -r kentmp3 18 | write -c kmp3lista.txt }
on 1:dialog:kentmp3:sclick:17:{  
  if (!$dialog(k3busca)) { 
    if (%k3bsi == si) { set %k3bdir $$sdir(%kb3dir,Seleciona el directorio raiz de todas tus carpetas de mp3z) }
    if (%k3bdir != $null) { k3busca | set %k3bsi no }
  }
  else { echo -a 4,1ERROR el buscador ya se encuentra activo } 
}
on 1:dialog:kentmp3:dclick:18:{ tocar | did -h kentmp3 10 | did -v kentmp3 9 | set %k3conre $did(kentmp3,18).seltext }
on 1:dialog:kentmp3:close:0:{ 
  splay stop 
  if ($dialog(k3busca)) { .dialog -x k3busca k3busca } 
  if ($dialog(k3canales)) { .dialog -x k3canales k3canales } 
  if ($dialog(k3colores)) { .dialog -x k3colores k3colores }
}
on 1:dialog:kentmp3:sclick:26:{ k3arch.del }
on 1:mp3end:{ 
  if (%kcontinuo == si) {
    did -c kentmp3 18 $iif($calc($did(kentmp3,18).sel + 1) <= $did(kentmp3,18).lines,$ifmatch,$did(kentmp3,18).lines)
    if ($did(kentmp3,18).sel == $did(kentmp3,18).lines) && ($did(kentmp3,18).lines != 1) && (%k3conre == $did(kentmp3,18).seltext) { /did -c kentmp3 18 1 }
    set %k3conre $did(kentmp3,18).seltext
    .tocar 
  }
}

;******* eventos k3busca

on 1:dialog:k3busca:init:0:{ 
  k3blista 
  if (%k3check == no) { did -c k3busca 20 }
  if (%k3radio == 1) { did -c k3busca 5 }
  if (%k3radio == 2) { did -c k3busca 6 }
  if (%k3radio == 3) { did -c k3busca 7 } 
}

on 1:dialog:k3busca:edit:2:{ set %k3btema $did(2) | .did -r k3busca 3 | k3blista2 }
on 1:dialog:k3busca:sclick:5:{ set %k3radio 1 }
on 1:dialog:k3busca:sclick:6:{ set %k3radio 2 }
on 1:dialog:k3busca:sclick:7:{ set %k3radio 3 }
on 1:dialog:k3busca:sclick:9:{ 
  set %k3bdir $$sdir(%kb3dir,Seleciona el directorio raiz de todas tus carpetas de mp3z)
  did -r k3busca 3
  k3blista 
}
on 1:dialog:k3busca:sclick:20:{
  if (%k3check == no) { set %k3check si } 
  else { set %k3check no }
}
on 1:dialog:k3busca:dclick:3:{ 
  set %k3btema $did(k3busca,3).seltext
  if (%k3radio == 1) { k3agrega | set %k3conre $did(kentmp3,18).seltext }
  if (%k3radio == 2) { k3agrega | tocar2 | set %k3conre $did(k3busca,3).seltext }
  if (%k3radio == 3) { tocar2 } 
  if ($did(20).state = 1) { .dialog -x k3busca k3busca } 
}

;*****eventos k3canales
on 1:dialog:k3canales:init:0:{ k3canal.llenar | set %k3canal $null }
on 1:dialog:k3canales:edit:24:{ set %k3canal $did(24) }
on 1:dialog:k3canales:sclick:27:{ k3canal.add }
on 1:dialog:k3canales:sclick:28:{ k3canal.del }

;*****eventos k3colores

on 1:dialog:k3colores:init:0:{ 
  .did -i k3colores 30 1 %k3color.inicio 
  .did -i k3colores 32 1 %k3color.segundo
  .did -i k3colores 34 1 %k3color.tercero
  .did -i k3colores 36 1 %k3color.cuarto
  .did -i k3colores 38 1 %k3color.ultimo  
}
on 1:dialog:k3colores:sclick:39:{
  .set %k3color.inicio $did(k3colores,30).text
  .set %k3color.segundo $did(k3colores,32).text
  .set %k3color.tercero $did(k3colores,34).text
  .set %k3color.cuarto $did(k3colores,36).text
  .set %k3color.ultimo $did(k3colores,38).text
}

menu channel { 
  - 
  KentMp3:{ k3abrir.re }
  - 
}
</font></pre>